Visual Basic 6 Black Book
(Publisher: The Coriolis Group)
Author(s): Steven Holzner
ISBN: 1576102831
Publication Date: 08/01/98

Drawing Boxes

You draw boxes in forms and picture boxes with the Line method, using the B argument:

object.Line [Step] (  x1, y1) [Step] (  x2, y2), [color], [B][F]

Here are the arguments you pass to Line:

•  Step—Keyword specifying that the starting point coordinates are relative to the current graphics position given by the CurrentX and CurrentY properties.

•  x1, y1—Single values indicating the coordinates of the starting point for the line or rectangle. The ScaleMode property determines the unit of measure used. If omitted, the line begins at the position indicated by CurrentX and CurrentY.

•  Step—Keyword specifying that the end point coordinates are relative to the line starting point.

•  x2, y2—Single values indicating the coordinates of the end point for the line being drawn.

•  color—Long integer value indicating the RGB color used to draw the line. If omitted, the ForeColor property setting is used. You can use the RGB function or QBColor function to specify the color.

•  B—If included, causes a box to be drawn using the coordinates to specify opposite corners of the box.

•  F—If the B option is used, the F option specifies that the box is filled with the same color used to draw the box. You cannot use F without B. If B is used without F, the box is filled with the current FillColor and FillStyle. The default value for FillStyle is transparent.

Let’s see an example showing how to draw boxes in forms and picture boxes when the user clicks a command button. In this case, we’ll draw a box in a form

Private Sub Command1_Click()

    Line (ScaleWidth / 4, ScaleHeight / 4)–(3 * ScaleWidth / 4, 3 * _
        ScaleHeight / 4), , B
…

and another box in a picture box:

Private Sub Command1_Click()
    Line (ScaleWidth / 4, ScaleHeight / 4)–(3 * ScaleWidth / 4, 3 * _
        ScaleHeight / 4), , B

    Picture1.Line (Picture1.ScaleWidth / 4, Picture1.ScaleHeight / 4)–_
        (3 * Picture1.ScaleWidth / 4, 3 * Picture1.ScaleHeight / 4), , B

End Sub

The result of this code appears in Figure 18.5. Now we’re drawing boxes in Visual Basic.

Figure 18.5   Drawing boxes in forms and picture boxes.

Drawing Circles

You use the Circle method to draw circles in forms and picture boxes:

object.Circle [Step] (x, y), radius, [color, [start, end, [aspect]]]

Here are the arguments you pass to Circle:

•  Step—Keyword specifying that the center of the circle, ellipse, or arc is relative to the current coordinates given by the CurrentX and CurrentY properties of object.

•  x, y—Single values indicating the coordinates for the center point of the circle, ellipse, or arc. The ScaleMode property of object determines the units of measure used.

•  radius—Single value indicating the radius of the circle, ellipse, or arc. The ScaleMode property of object determines the unit of measure used.

•  color—Long integer value indicating the RGB color of the circle’s outline. If omitted, the value of the ForeColor property is used. You can use the RGB function or QBColor function to specify the color.

•  start, end—Single-precision values. When an arc or a partial circle or ellipse is drawn, start and end specify (in radians) the beginning and end positions of the arc. The range for both is –2 pi radians to 2 pi radians. The default value for start is 0 radians; the default for end is 2 * pi radians.

•  aspect—Single-precision value indicating the aspect ratio of the circle. The default value is 1.0, which yields a perfect (nonelliptical) circle on any screen.

As an example, we draw the biggest circle possible in both a form and a picture box, Picture1, when the user clicks a command button, Command1, using this code, and using a Switch function to determine if the form’s width or height is larger:

Private Sub Command1_Click()
    Circle (ScaleWidth / 2, ScaleHeight / 2), _
        Switch(ScaleWidth >= ScaleHeight, ScaleHeight / 2, _
        ScaleWidth < ScaleHeight, ScaleWidth / 2)

     Picture1.Circle (Picture1.ScaleWidth / 2, Picture1.ScaleHeight / 2), _
        Switch(Picture1.ScaleWidth >= Picture1.ScaleHeight, _
        Picture1.ScaleHeight / 2, Picture1.ScaleWidth < _
        Picture1.ScaleHeight, Picture1.ScaleWidth / 2)

End Sub

Running this code gives us the result you see in Figure 18.6.

Figure 18.6   Drawing circles in forms and picture boxes.

The code for this example is located in the drawcircle folder on this book’s accompanying CD-ROM.